/\*

Simulation of a randomized controlled trial, with a single pre-test and two post-tests, post1 and post2.

The two post-tests are sufficiently separated for the individual responses to change between the tests.

Thus there are sustained and one-time-only individual responses in the post-tests in both groups.

The individual responses in the control group represent changes in indviduals that might occur

 when there are substantial periods between pre and post1, and between post1 and post2.

 Hence the individual responses in the control group are added to the exptal group, but the exptal

 group has extra sustained and one-time-only individual responses. These are the net individual

 responses due to the treatment, and the aim of the analysis is to estimate them and also the

 net mean change in the two post tests (and the mean of these).

Measurement errors are the same in control and exptal groups in the pre test.

Measurement error changes between pre and post1 but is the same in both post-tests in both groups.

 However, the one-time-only individual responses in the control group (which are added also to the

 experimental group) result in effectively different errors in post1 (the same in both groups) and post2

 (the same in both groups).

This version generates data for a gender effect, but the gender effect is not estimated.

 If you have a gender or other group effect (other than the control vs exptal), you should perform

 separate analyses for the groups to properly account for and estimate separate errors, individual

 responses, treatment effects and modifying effects of covariates. Compare the errors and effects

 using the combine/compare effects spreadsheet at sportsci.org.

The linear effects of pre-test VO2max and another covariate X are also estimated, but the simulation

 does not generate effects for these two variables.

Owing to the complexities arising from changes in the individual responses, this simulation does not

 include estimation of proportions of responders in the simulated samples or of chances that each

 individual is a responder, and there is no bootstrapping of confidence limits.

This program runs in SAS Studio or the full SAS program (with output to the listing window).

It is set to run 10 simulated trials. Many more are needed to properly assess the confidence limits.

\*/

options notes nodate number stimer;

title;

\*ods \_ALL\_ close; \*unstar this if want output only to the listing window in the main SAS package;

ods graphics off;

ods listing;

run;

ods select all;

options ps=61 ls=110 pageno=1;

\*generate data;

\*the most important values to play with are shown highlighted;

%let dep=VO2maxDelta; \*also works for VO2maxPost, but model might need tweaking;

%let NoOfTrials=10;

%let ss=80; \*sample size in each of the two groups;

%let Mean=40; \*in ml/min/kg;

%let SD=7; \*ditto;

%let errorpre=2; \*2 is equivalent to 2/40\*100=5%;

%let errorpost=1.5;

%let Magnithresh=1.5; \*if SD=7, 1.5 is equivalent to 1.5/SD = 1.5/7 = 0.21. Default smallest important=0.20;

%let ExpMeanPost1=4.0; \*net mean effect of treatment, 4.0 is equivalent to 4.0/mean\*100 = 10%, if mean=40;

%let ExpMeanPost2=2.5; \*there is no point in simulating mean changes in the control group;

%let CtlSD=2; \*SD of individual responses in control and exptal group, representing stable changes;

%let CtlSDPost1=1; \*one-time indiv responses on first post test in both groups;

%let CtlSDPost2=2; \*one-time indiv responses on second post test in both groups;

%let ExpSD=4; \*extra SD of sustained individual responses in exptal group, must be >=|Xsd\*Xslope|;

%let ExpSDPost1=3; \*extra one-time indiv responses on first post test;

%let ExpSDPost2=1; \*extra one-time indiv responses on second post test;

%let FemaleMean=0; \*male mean will be set to equal and opposite; \*not used here;

%let Xmean=1; \*mean of a covariate, e.g. log2(h/wk mod-vig activity), so 1 represents 2 h/wk;

%let Xsd=1; \*sd of above covariate, so 1 represents a (factor) SD of ×⁄÷2;

%let Xslope=0; \*change in ExpMean per unit of difference of X from Xmean;

\*If Xmean=1, Xslope=-1, ExpMean=4.5, then, e.g. for X=3, treatment effect = ExpMean-1\*(3-1) = 4.5-2 = 2.5;

%let alpha=0.1; \*alpha level for confidence limits;

%let nob=nobound; \*allow negative variance in the mixed model;

%let logflag=0; \*set to 1 for log transformation, not used for these simulations;

%let deceffect=1; \*decimal place for the effects;

%let decdep=1; \*decimal place for the means and SD of the dependent;

title1 "&dep RCT, smallest effect=&Magnithresh.. Pre-test: mean=&mean, SD=&sd, error=&errorpre; DeltaPost1=&ExpMeanPost1, DeltaPost2=&ExpMeanPost2";

title2 "Error in post tests=&errorpost.. Control&Exptal indiv. responses: SustainedIR=&CtlSD, IRpost1=&CtlSDPost1, IRpost2=&CtlSDPost2";

title3 "Extra Exptal indiv. responses: SustainedIR=&ExpSD, ExtraIRpost1=&ExpSDPost1, ExtraIRpost2=&ExpSDPost2";

\*title4 "Female mean extra individual response=&FemaleMean male mean extra=-&FemaleMean";

title4 "Covariate X estimated but not simulated; no gender effect; group sample size=&ss.";

data dat1;

do Trial=1 to &NoOfTrials;

Group="Control";

xVarExp=0;

xVarExpPost1=0;

xVarExpPost2=0;

\*xVarCtl=1;

do SubjectID=1 to &ss;

 Gender="Female";

 if mod(SubjectID,2)=0 then Gender="Male";

 VO2maxTrue=&Mean+rannor(0)\*&SD;

 VO2maxPre=VO2maxTrue+rannor(0)\*&errorpre;

 X=&Xmean+rannor(0)\*&Xsd; \*random normal covariate;

 SustainedIR=rannor(0)\*&CtlSD;

 IndivResponse1=SustainedIR+rannor(0)\*&CtlSDPost1;

 IndivResponse2=SustainedIR+rannor(0)\*&CtlSDPost2;

 VO2maxPost1=VO2maxTrue+rannor(0)\*&errorpost+IndivResponse1;

 VO2maxDelta1=VO2maxPost1-VO2maxPre;

 VO2maxPost2=VO2maxTrue+rannor(0)\*&errorpost+IndivResponse2;

 VO2maxDelta2=VO2maxPost2-VO2maxPre;

 output;

 end;

Group="Exptal";

xVarExp=1;

\*xVarCtl=0;

do SubjectID=&ss+1 to 2\*&ss;

 Gender="Female";

 if mod(SubjectID,2)=0 then Gender="Male";

 VO2maxTrue=&Mean+rannor(0)\*&SD;

 VO2maxPre=VO2maxTrue+rannor(0)\*&errorpre;

 X=&Xmean+rannor(0)\*&Xsd; \*random normal covariate;

 SustainedIR=rannor(0)\*&CtlSD+rannor(0)\*&ExpSD;

 IndivResponse1=&ExpMeanPost1+SustainedIR+rannor(0)\*&CtlSDPost1+rannor(0)\*&ExpSDPost1;

 IndivResponse2=&ExpMeanPost2+SustainedIR+rannor(0)\*&CtlSDPost2+rannor(0)\*&ExpSDPost2;

 VO2maxPost1=VO2maxTrue+rannor(0)\*&errorpost+IndivResponse1;

 VO2maxDelta1=VO2maxPost1-VO2maxPre;

 VO2maxPost2=VO2maxTrue+rannor(0)\*&errorpost+IndivResponse2;

 VO2maxDelta2=VO2maxPost2-VO2maxPre;

 output;

 end;

end;

run;

/\*

title6 "First few observations";

options ls=175;

proc print data=dat1(obs=40);

format VO2maxTrue--VO2maxDelta2 5.1;

run;

\*/

options ls=110 ps=70 pageno=1;

title6 "Basic stats for first trial";

proc means mean std min max maxdec=1 fw=7 data=dat1;

var VO2maxPre VO2maxPost1 VO2maxPost2 VO2maxDelta1 VO2maxDelta2 X;

class Group ;

\*by Trial;

where Trial=1;

run;

title6 "Population proportions of net responders";

data props1;

DataGroup="Popn";

\*do Gender="Female","Male";

do Gender="Both";

 IndividualResponse="Total in Post1 ";

 IndividualResponseSD=sqrt(&ExpSD\*\*2+&ExpSDPost1\*\*2);

 if IndividualResponseSD=0 then ExpSD=1E-7;

 NetMeanChange=&ExpMeanPost1;

 PropPosResponders=

 100\*(1-probnorm(-(&ExpMeanPost1+&FemaleMean-2\*(Gender="Male")\*&FemaleMean-&MagniThresh)/IndividualResponseSD));

 PropNegResponders=

 100\*probnorm(-(&magnithresh+&FemaleMean-2\*(Gender="Male")\*&FemaleMean+&ExpMeanPost1)/IndividualResponseSD);

 PropTrivResponders=100-PropPosResponders-PropNegResponders;

 output;

 IndividualResponse="Sustained in Post1";

 IndividualResponseSD=&ExpSD;

 if IndividualResponseSD=0 then ExpSD=1E-7;

 PropPosResponders=

 100\*(1-probnorm(-(&ExpMeanPost1+&FemaleMean-2\*(Gender="Male")\*&FemaleMean-&MagniThresh)/IndividualResponseSD));

 PropNegResponders=

 100\*probnorm(-(&magnithresh+&FemaleMean-2\*(Gender="Male")\*&FemaleMean+&ExpMeanPost1)/IndividualResponseSD);

 PropTrivResponders=100-PropPosResponders-PropNegResponders;

 output;

 IndividualResponse="Sustained in Post2";

 IndividualResponseSD=&ExpSD;

 if IndividualResponseSD=0 then ExpSD=1E-7;

 NetMeanChange=&ExpMeanPost2;

 PropPosResponders=

 100\*(1-probnorm(-(&ExpMeanPost2+&FemaleMean-2\*(Gender="Male")\*&FemaleMean-&MagniThresh)/IndividualResponseSD));

 PropNegResponders=

 100\*probnorm(-(&magnithresh+&FemaleMean-2\*(Gender="Male")\*&FemaleMean+&ExpMeanPost2)/IndividualResponseSD);

 PropTrivResponders=100-PropPosResponders-PropNegResponders;

 output;

 IndividualResponse="Total in Post2";

 IndividualResponseSD=sqrt(&ExpSD\*\*2+&ExpSDPost2\*\*2);

 if IndividualResponseSD=0 then ExpSD=1E-7;

 PropPosResponders=

 100\*(1-probnorm(-(&ExpMeanPost2+&FemaleMean-2\*(Gender="Male")\*&FemaleMean-&MagniThresh)/IndividualResponseSD));

 PropNegResponders=

 100\*probnorm(-(&magnithresh+&FemaleMean-2\*(Gender="Male")\*&FemaleMean+&ExpMeanPost2)/IndividualResponseSD);

 PropTrivResponders=100-PropPosResponders-PropNegResponders;

 output;

 end;

\*drop ExpSD;

proc print noobs data=props1;

var IndividualResponse NetMeanChange IndividualResponseSD PropNegResponders PropTrivResponders PropPosResponders;

format \_numeric\_ 5.1;

run;

proc standard data=dat1 mean=0 std=0.5 out=dat2;

var VO2maxPre X;

by Trial;

\*make dataset in long format for the two post tests;

data dat3;

set dat2;

Time="Post1";

&dep=&dep.1;

if Group="Exptal" then do;

 xVarExpPost1=1;

 xVarExpPost2=0;

 end;

output;

Time="Post2";

&dep=&dep.2;

if Group="Exptal" then do;

 xVarExpPost1=0;

 xVarExpPost2=1;

 end;

output;

run;

\*set up a star to suppress titles with (raw) when not using log transformation;

data \_null\_;

if "&logflag"="1" then call symput('star',"\*");

else call symput('star',"");

run;

data clev pred pred1 pred2 predm predm1 est est1 estCohen lsm lsm1 lsmdiff lsmdiff1 lsmdiff2

 cov cov0 cov1 cov2 cov3 covsum solf solf1 solr solr1;

data pred0a predm0a cov0a est0a lsmdiff0a;

/\*

options ls=180;

proc print data=dat3;run;

\*/

run;

ods select none; \*for running in SAS Studio;

ods listing close;

\*mixed model with usual extra variance in exptal group;

proc mixed data=dat3 covtest cl alpha=&alpha &nob;

class SubjectID Group Time;

model &dep=Group Group\*Time Group\*Time\*VO2maxPre Group\*Time\*X/s ddfm=sat outp=pred residual noint;

\*model VO2maxPost=Group Group\*VO2maxPre Group\*X Group\*Gender/s ddfm=sat outp=pred outpm=predm residual noint;

random int/subject=SubjectID s cl alpha=&alpha;

random xVarExpPost1 xVarExpPost2/subject=SubjectID s cl alpha=&alpha type=un;

\*replace the above 2 random steps with the next random to estimate one-time only indiv responses;

\*random int xVarExpPost1 xVarExp xVarExpPost2/subject=SubjectID s cl alpha=&alpha;

repeated/group=Time;

lsmeans Group/diff=control('Control') alpha=&alpha; \*star this off when including Gender;

\*lsmeans Group\*Time/diff=control('Control' 'Post1') alpha=&alpha; \*these get too complicated;

\*lsmeans Group\*Time/diff=control('Control' 'Post2') alpha=&alpha; \*better to use estimate statements;

\*lsmeans Group\*Gender/diff=control('Control' 'Male') alpha=&alpha; \*unstar when including Gender;

\*lsmeans Group\*Gender/diff=control('Control' 'Female') alpha=&alpha; \*unstar when including Gender;

estimate "Least-squares mean changes:";

estimate "Control @ Post1" Group 1 0 Group\*Time 1 0 0 0/cl alpha=&alpha;

estimate "Exptal @ Post1" Group 0 1 Group\*Time 0 0 1 0/cl alpha=&alpha;

estimate "Exptal-Control" Group -1 1 Group\*Time -1 0 1 0/cl alpha=&alpha;

estimate "";

estimate "Control @ Post2" Group 1 0 Group\*Time 0 1 0 0/cl alpha=&alpha;

estimate "Exptal @ Post2" Group 0 1 Group\*Time 0 0 0 1/cl alpha=&alpha;

estimate "Exptal-Control" Group -1 1 Group\*Time 0 -1 0 1/cl alpha=&alpha;

estimate "";

estimate "Effect of 2SD of VO2maxPre Post1:";

estimate " Control 2SD of VO2maxPre" Group\*Time\*VO2maxPre 1 0 0 0/cl alpha=&alpha;

estimate " Exptal 2SD of VO2maxPre" Group\*Time\*VO2maxPre 0 0 1 0/cl alpha=&alpha;

estimate " Expt-Cont 2SD of VO2maxPre" Group\*Time\*VO2maxPre -1 0 1 0/cl alpha=&alpha;

estimate "Effect of 2SD of X Post1:";

estimate " Control 2SD of X" Group\*Time\*X 1 0 0 0/cl alpha=&alpha;

estimate " Exptal 2SD of X" Group\*Time\*X 0 0 1 0/cl alpha=&alpha;

estimate " Expt-Cont 2SD of X" Group\*Time\*X -1 0 1 0/cl alpha=&alpha;

\*not shown are estimate statements for modification in Post2;

/\*

estimate "Effect of Gender:";

estimate " Female Expt-Control" Group -1 1 Group\*Gender -1 0 1 0/cl alpha=&alpha;

estimate " Male Exptal-Control" Group -1 1 Group\*Gender 0 -1 0 1/cl alpha=&alpha;

estimate " Control F-M" Group\*Gender 1 -1 0 0/cl alpha=&alpha;

estimate " Exptal F-M" Group\*Gender 0 0 1 -1/cl alpha=&alpha;

estimate " Expt-Cont F-M" Group\*Gender -1 1 1 -1/cl alpha=&alpha;

\*/

ods output covparms=cov;

ods output estimates=est;

ods output lsmeans=lsm;

ods output diffs=lsmdiff;

\*ods output solutionr=solr;

\*ods output solutionf=solf;

\*ods output classlevels=clev;

by Trial;

run;

ods listing;

ods select all;

title6 "SD (%) of random effects in original sample, with conf. limits via proc mixed, first 10 trials";

&star.title6 "SD (raw) of random effects in original sample, with conf. limits via proc mixed, first 10 trials";

title7 "Intercept is pre-test adjusted pre-test error plus shared sustained indiv. responses";

title8 "Residual is total error in the post tests, the sum of typical error and one-time control ind. responses.";

title9 "UN(1,1) & UN(2,2) are observed exptal indiv. resp. in Post1 & Post2, UN(2,1) is sustained indiv. resp.";

title10 "xVarExp is exptal sustained and xVarExpPost1 xVarExpPost2 are one-time only indiv. responses.";

data cov1;

set cov;

DegFree=2\*Zvalue\*\*2;

a=1;b=1;c=1;

if estimate<0 then a=-1;

if lower<0 then b=-1;

if upper<0 then c=-1;

SD=a\*sqrt(a\*estimate);

lower=b\*sqrt(b\*lower);

upper=c\*sqrt(c\*upper);

array r estimate lower upper;

if &logflag=1 then do over r;

 r=100\*exp(r/100)-100;

 end;

CLtd=sqrt(upper/lower);

if covparm ne "Residual" then do;

 CLtd=.;

 CLpm=(upper-lower)/2;

 \*DegFree=.;

 end;

data cov2;

set cov1;

Group=substr(Group,6);

DataGroup="Sample ";

data covpop;

DataGroup="Population";

Subject="SubjectID";

\*Group=" ";

CovParm="Intercept ";

Subject="SubjectID";

\*Group=" ";

SD=sqrt((1-&errorpre\*\*2/(&SD\*\*2\*\*2+&errorpre\*\*2))\*&errorpre\*\*2+&CtlSD\*\*2); \*adjusted for VO2maxPre;

output;

CovParm="xVarExpPost1";

SD=&ExpSDPost1;

output;

CovParm="xVarExp";

SD=&ExpSD;

output;

CovParm="xVarExpPost2";

SD=&ExpSDPost2;

output;

CovParm="UN(1,1)";

SD=sqrt(&ExpSDPost1\*\*2+&ExpSD\*\*2);

output;

CovParm="UN(2,1)";

SD=&ExpSD;

output;

CovParm="UN(2,2)";

SD=sqrt(&ExpSDPost2\*\*2+&ExpSD\*\*2);

output;

CovParm="Residual";

Subject="";

Group="Post1";

SD=sqrt(&errorpost\*\*2+&CtlSDPost1\*\*2);

output;

Group="Post2";

SD=sqrt(&errorpost\*\*2+&CtlSDPost2\*\*2);

output;

run;

data cov3;

set covpop cov2;

proc sort;

by covparm group;

options ls=110 ps=90;

proc print data=cov3 noobs;

var Trial DataGroup Group covparm subject SD lower upper CLpm CLtd alpha;

format SD lower upper CLpm 5.&deceffect CLtd 5.2;

where Trial<11;

run;

options ls=110;

title6 "Least-squares means and differences (%) averaged over post1 and post2";

&star.title6 "Least-squares means and differences (raw) averaged over post1 and post2";

data lsmdiff1;

set lsm lsmdiff;

array a estimate lower upper;

if &logflag then do over a;

 a=exp(a/100);

 end;

CLpm=(upper-lower)/2;

proc sort;

by Trial;

title7 "for first 5 trials";

proc print noobs;

var Trial Group \_Group estimate clpm lower upper df alpha;

format estimate clpm lower upper 5.&decdep df 5.0;

\*by Group;

where Trial<6;

by Trial;

run;

title6 "MBI for differences in least-squares means for first 5 trials";

\*all the same as for fixed effects, but with est datasets replaced by lsmdiff;

\*and label replaced by Group \_Group or whatever nominal predictors in the proc prints;

\*could do similar for the lsmeans (which would be appropriate when modeling change scores);

data lsmdiff1;

set lsm lsmdiff;

length Prob $ 8 Magni $ 4;

MagniThresh=&MagniThresh;

ChancePos=100\*(1-ProbT(-(estimate-abs(MagniThresh))/StdErr,DF));

ChanceNeg=100\*ProbT(-(estimate+abs(MagniThresh))/StdErr,DF);

if &LogFlag=1 then do;

 if Magnithresh>0 then do;

 ChancePos=100\*(1-ProbT(-(estimate-100\*log(1+MagniThresh/100))/StdErr,DF));

 ChanceNeg=100\*ProbT(-(estimate+100\*log(1+MagniThresh/100))/StdErr,DF);

 end;

 else do;

 ChancePos=100\*(1-ProbT(-(estimate+100\*log(1+MagniThresh/100))/StdErr,DF));

 ChanceNeg=100\*ProbT(-(estimate-100\*log(1+MagniThresh/100))/StdErr,DF);

 end;

 end;

ChanceTriv=100-ChancePos-ChanceNeg;

ORPosNeg=ChancePos/(100-ChancePos)/(ChanceNeg/(100-ChanceNeg));

ORNegPos=1/ORPosNeg;

ClinFlag=1; \*want all inferences to be clinical initially;

\*if index(label,"2SD") then ClinFlag=0; \*covariates definitely need to be non-clinical;

\*clinical inferences;

if clinflag then do;

ChPos=ChancePos; ChNeg=ChanceNeg;

if MagniThresh<0 then do;

 ChPos=ChanceNeg; ChNeg=ChancePos;

 end;

Prob=""; Magni=""; ClearOrNot="unclear";

if ChNeg<0.5 then do;

 ClearOrNot="@25/.5%";

 if ChNeg<0.1 then ClearOrNot="@5/.1% ";

 if ChanceTriv>25 then Magni="triv";

 if ChPos>25 then Magni="bene";

 Prob="possibly";

 if ChPos>75 or ChanceTriv>75 then Prob="likely ";

 if ChPos>95 or ChanceTriv>95 then Prob="v.likely";

 if ChPos>99.5 or ChanceTriv>99.5 then Prob="m.likely";

 end;

else do; \*i.e., ChNeg>0.5;

 if ChPos<25 then do;

 ClearOrNot="@25/.5%";

 if ChPos<5 then ClearOrNot="@5/.1% ";

 if ChanceTriv>25 then Magni="triv";

 if ChNeg>25 then Magni="harm";

 Prob="possibly";

 if ChNeg>75 or ChanceTriv>75 then Prob="likely ";

 if ChNeg>95 or ChanceTriv>95 then Prob="v.likely";

 if ChNeg>99.5 or ChanceTriv>99.5 then Prob="m.likely";

 end;

 end;

if ClearOrNot="unclear" and

 (MagniThresh>0 and ORPosNeg>25/75/(0.5/99.5) or MagniThresh<0 and ORNegPos>25/75/(0.5/99.5))

 then do;

 ClearOrNot="OR>66.3";

 Magni="bene";

 if ChPos>25 then Prob="possibly";

 if ChPos>75 then Prob="likely ";

 if ChPos>95 then Prob="v.likely";

 if ChPos>99.5 then Prob="m.likely";

 end;

output;

end;

\*mechanistic inferences;

ClinFlag=0;

ClearOrNot="unclear";

Prob="";

Magni="";

ORPosNeg=.; ORNegPos=.;

if ChanceNeg<5 or ChancePos<5 then ClearOrNot="@90% ";

if ChanceNeg<0.5 or ChancePos<0.5 then ClearOrNot="@99% ";

if ClearOrNot ne "unclear" then do;

 Magni="+ive ";

 if estimate<0 then Magni="-ive ";

 if ChancePos>5 or ChanceNeg>5 then Prob="unlikely";

 if ChancePos>25 or ChanceNeg>25 then Prob="possibly";

 if ChancePos>75 or ChanceNeg>75 then Prob="likely ";

 if ChancePos>95 or ChanceNeg>95 then Prob="v.likely";

 if ChancePos>99.5 or ChanceNeg>99.5 then Prob="m.likely";

 end;

if ClearOrNot ne "unclear" and ChanceTriv>75 then do;

 Magni="triv.";

 Prob="likely ";

 if ChanceTriv>95 then Prob="v.likely";

 if ChanceTriv>99.5 then Prob="m.likely";

 end;

\*end;

output;

data lsmdiff2;

set lsmdiff1;

if estimate=0 then do;

 estimate=.; magnithresh=.; magni=""; clearornot="";

 end;

array a estimate lower upper;

if &logflag then do over a;

 a=100\*exp(a/100)-100;

 end;

CLpm=(Upper-lower)/2;

rename df=DegFree;

run;

proc sort;

by Trial;

title7 "Clinical inferences for mean change averaged over post1 and post2";

title8 "Magnithresh is smallest beneficial change";

options ls=145 ps=80;

proc print data=lsmdiff2 noobs;

where clinflag=1 and Trial<6;

var Trial Group \_Group estimate CLpm lower upper alpha DegFree

 MagniThresh ChanceNeg ChanceTriv ChancePos ORPosNeg ORNegPos Prob Magni ClearOrNot;

format estimate CLpm lower upper MagniThresh 5.&deceffect Probt best5. ORPosNeg ORNegPos 5.0 ChanceNeg ChanceTriv

 ChancePos 5.1 DegFree 5.0;

\*format estimate CLpm lower upper MagniThresh &form Probt best5. ORPosNeg ORNegPos 5.0 ChanceNeg ChanceTriv

 ChancePos 5.1 DegFree 5.0;

by Trial;

run;

\*FIXED EFFECTS;

title6 "Fixed effects (%)";

&star.title6 "Fixed effects (raw)";

title7 "for original sample in first 5 trials";

data est1;

set est;

if estimate=0 then estimate=.;

array a estimate lower upper;

if &logflag=1 then do over a;

 a=100\*exp(a/100)-100;

 end;

CLpm=(Upper-lower)/2;

\*proc sort;

\*by label;

options ls=110 ps=90;

proc print data=est1 noobs;

var Trial Label estimate CLpm lower upper alpha DF ;

format estimate stderr CLpm lower upper 5.&deceffect Probt best5. DF 5.0;

\*by label;

by Trial;

pageby Trial;

where Trial<6;

run;

\*magnitude-based inferences for fixed effects;

\*clin and non-clin MBIs are output and listed separately;

title6 "MBI for fixed effects";

data est1;

set est;

length Prob $ 8 Magni $ 4;

MagniThresh=&MagniThresh;

ChancePos=100\*(1-ProbT(-(estimate-abs(MagniThresh))/StdErr,DF));

ChanceNeg=100\*ProbT(-(estimate+abs(MagniThresh))/StdErr,DF);

if &LogFlag=1 then do;

 if Magnithresh>0 then do;

 ChancePos=100\*(1-ProbT(-(estimate-100\*log(1+MagniThresh/100))/StdErr,DF));

 ChanceNeg=100\*ProbT(-(estimate+100\*log(1+MagniThresh/100))/StdErr,DF);

 end;

 else do;

 ChancePos=100\*(1-ProbT(-(estimate+100\*log(1+MagniThresh/100))/StdErr,DF));

 ChanceNeg=100\*ProbT(-(estimate-100\*log(1+MagniThresh/100))/StdErr,DF);

 end;

 end;

ChanceTriv=100-ChancePos-ChanceNeg;

ORPosNeg=ChancePos/(100-ChancePos)/(ChanceNeg/(100-ChanceNeg));

ORNegPos=1/ORPosNeg;

ClinFlag=1; \*want all inferences to be clinical initially;

if index(label,"2SD") then ClinFlag=0; \*covariates definitely need to be non-clinical;

\*clinical inferences;

if clinflag then do;

ChPos=ChancePos; ChNeg=ChanceNeg;

if MagniThresh<0 then do;

 ChPos=ChanceNeg; ChNeg=ChancePos;

 end;

Prob=""; Magni=""; ClearOrNot="unclear";

if ChNeg<0.5 then do;

 ClearOrNot="@25/.5%";

 if ChNeg<0.1 then ClearOrNot="@5/.1% ";

 if ChanceTriv>25 then Magni="triv";

 if ChPos>25 then Magni="bene";

 Prob="possibly";

 if ChPos>75 or ChanceTriv>75 then Prob="likely ";

 if ChPos>95 or ChanceTriv>95 then Prob="v.likely";

 if ChPos>99.5 or ChanceTriv>99.5 then Prob="m.likely";

 end;

else do; \*i.e., ChNeg>0.5;

 if ChPos<25 then do;

 ClearOrNot="@25/.5%";

 if ChPos<5 then ClearOrNot="@5/.1% ";

 if ChanceTriv>25 then Magni="triv";

 if ChNeg>25 then Magni="harm";

 Prob="possibly";

 if ChNeg>75 or ChanceTriv>75 then Prob="likely ";

 if ChNeg>95 or ChanceTriv>95 then Prob="v.likely";

 if ChNeg>99.5 or ChanceTriv>99.5 then Prob="m.likely";

 end;

 end;

if ClearOrNot="unclear" and

 (MagniThresh>0 and ORPosNeg>25/75/(0.5/99.5) or MagniThresh<0 and ORNegPos>25/75/(0.5/99.5))

 then do;

 ClearOrNot="OR>66.3";

 Magni="bene";

 if ChPos>25 then Prob="possibly";

 if ChPos>75 then Prob="likely ";

 if ChPos>95 then Prob="v.likely";

 if ChPos>99.5 then Prob="m.likely";

 end;

output;

end;

\*mechanistic inferences;

ClinFlag=0;

ClearOrNot="unclear";

Prob="";

Magni="";

ORPosNeg=.; ORNegPos=.;

if ChanceNeg<5 or ChancePos<5 then ClearOrNot="@90% ";

if ChanceNeg<0.5 or ChancePos<0.5 then ClearOrNot="@99% ";

if ClearOrNot ne "unclear" then do;

 Magni="+ive ";

 if estimate<0 then Magni="-ive ";

 if ChancePos>5 or ChanceNeg>5 then Prob="unlikely";

 if ChancePos>25 or ChanceNeg>25 then Prob="possibly";

 if ChancePos>75 or ChanceNeg>75 then Prob="likely ";

 if ChancePos>95 or ChanceNeg>95 then Prob="v.likely";

 if ChancePos>99.5 or ChanceNeg>99.5 then Prob="m.likely";

 end;

if ClearOrNot ne "unclear" and ChanceTriv>75 then do;

 Magni="triv.";

 Prob="likely ";

 if ChanceTriv>95 then Prob="v.likely";

 if ChanceTriv>99.5 then Prob="m.likely";

 end;

\*end;

output;

data est2;

set est1;

if estimate=0 then do;

 estimate=.; magnithresh=.; magni=""; clearornot=""; prob="";

 end;

array a estimate lower upper;

if &logflag then do over a;

 a=100\*exp(a/100)-100;

 end;

CLpm=(Upper-lower)/2;

rename df=DegFree;

run;

options ls=135 ps=90;

title7 "Clinical inferences for mean changes";

title8 "Magnithresh is smallest beneficial change";

proc print data=est2 noobs;

where clinflag=1 and index(Label,"2SD")=0 and Trial<6;

var label estimate CLpm lower upper alpha DegFree

 MagniThresh ChanceNeg ChanceTriv ChancePos ORPosNeg ORNegPos Prob Magni ClearOrNot;

format estimate CLpm lower upper MagniThresh 5.&decdep Probt best5. ORPosNeg ORNegPos 5.0

 ChanceNeg ChanceTriv ChancePos 5.1 DegFree 5.0;

by Trial;

run;

options ls=130 ps=90;

title7 "Non-clinical inferences for covariates";

title8 "Magnithresh is smallest change";

title9 "for original sample in first 5 trials";

proc print data=est2 noobs;

where clinflag=0 and Trial<6 and index(Label,"2SD");

var Trial label estimate CLpm lower upper alpha DegFree

 MagniThresh ChanceNeg ChanceTriv ChancePos Prob Magni ClearOrNot;

format estimate CLpm lower upper MagniThresh 5.&decdep Probt best5. ChanceNeg ChanceTriv

 ChancePos 5.1 DegFree 5.0;

by Trial;

run;

options ls=110;

\*this sound output does not work in SAS Studio;

data \_null\_;

call sound(440,200);

call sound(622,200);

call sound(880,200);

run;